***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 03, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P4SMAJ7P5CA 1 2 
.param
+vc0 = -5.992e-9 	vc1 = 0.116e-10 	vc2 = 4.643e-9		vc3 = 1.021e-0
+tc1 = 1.511e-3		tc2 = 5.601e-2	 	tc3 = 5.011e-3		tc4 = 2.371e-3
d1 1 c zener
g1 c 1 value = {(vc0+vc1*v(c,1)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+vc2*exp(vc3*v(c,1)))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d2 2 c zener
g2 c 2 value = {(vc0+vc1*v(c,2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+vc2*exp(vc3*v(c,2)))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model zener d
***** flag parameter *****
+level = 1   
***** dc model parameter *****
+ is = 1e-14		   n = 1		  rs = 1e-3
+ibv = 1e-3		 nbv = 1.5		  bv = 8.07
***** capacitance parameter *****
+cjo = 1.141e-9		   m = 2.117e-1		  vj = 1.317
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.11		 xti = 3
+trs1 = 1e-4		tbv1 = 4.337e-4
.ends P4SMAJ7P5CA
*$
